Home

Gnomonさん作

鋼_断面1.bat（鉄骨三部作① 鉄骨断面作図）の場合

現在公開しているBATファイルについては、こちら　をご覧下さい。

Gnomonさんが提供している外部変形は「REM #jww」の後に「REM #cd」が有りませんが、他でパスを設定しています。
付属の説明テキストにも書かれていますから、良く読んで理解しましょう。

+++鋼_断面1.bat（鉄骨三部作① 鉄骨断面作図）の場合+++

★BATファイルは以下のようになっています。

@rem 鉄骨三部作① (1-1) 鋼材断面作図
@rem ========================================================
@rem ① Ｈ形鋼
@rem ② 角形鋼管（正方形）
@rem ③ 円形鋼管
@rem ④ 等辺山形鋼
@rem ⑤ リップみぞ形鋼(Ｃチャン)
@rem ⑥ 重量溝形鋼
@rem by 杉井左内 (Gnomon,zzz@aeon7.com)
@rem ========================================================

@rem ver.0.01 1998.05.03 線種・線色指定化
@rem ver.0.02 1998.07.07 描画位置指定関係の改良
@rem ver.1.10 1998.10.30 レイヤ等管理の整理
@rem ver.1.20 2002.04.10 JWW版

@echo off
@cls
goto do%1

rem #jww
rem #hc【 Ｈ形鋼：左クリック　　□鋼管：右クリック 】
rem #hm |Ｈ形鋼|□鋼管|○鋼管|等辺アングル|Ｃチャン|重量溝形鋼|

rem #:1
rem #h0
rem #0 Ｈ形鋼の 図示位置を指示
rem #1 Ｈ形鋼の Ｙ軸方向を指示.
rem #c 描画基点　(1～9／CR=8): /_PT
rem #c 高さ　(mm／CR=250) : /_HH
rem #c 幅　(mm／CR=125) : /_BB
rem #c ウェブ厚　(mm／CR=6) : /_TW
rem #c フランジ厚　(mm／CR=9) : /_TF
rem #c フィレット　r(mm)(CR=略図／ｱﾙﾌｧﾍﾞｯﾄ=BH) : /_RR
rem #c 線種　(1～9／CR=実線): /_LT
rem #c 線色　(1～9／CR=4): /_LC
rem #hr
rem #e

rem #:2
rem #h0
rem #0 角形鋼管の 図示位置を指示
rem #1 角形鋼管の Ｙ軸方向を指示.
rem #c 描画基点　(1～9／CR=5): /_PT
rem #c 鋼管の径　(mm／CR=300) : /_BB
rem #c 肉厚　(mm／CR=12) : /_TT
rem #c 線種　(1～9／CR=実線): /_LT
rem #c 線色　(1～9／CR=4): /_LC
rem #hr
rem #e

rem #:3
rem #h0
rem #0 円形鋼管の 図示位置を指示
rem #1 円形鋼管の Ｙ軸方向を指示.
rem #c 描画基点　(1～9／CR=5): /_PT
rem #c 鋼管の径　(mm／CR=318.5) : /_DD
rem #c 肉厚　(mm／CR=12.7) : /_TT
rem #c 線種　(1～9／CR=実線): /_LT
rem #c 線色　(1～9／CR=4): /_LC
rem #hr
rem #e

rem #:4
rem #h0
rem #0 等辺山形鋼の 図示位置を指示
rem #1 等辺山形鋼の Ｙ軸方向を指示.
rem #c 描画基点　(1～9／CR=1) : /_PT
rem #c 縦(=横)　(mm／CR=65) : /_AA
rem #c 厚さ　(mm／CR=6) : /_TT
rem #c 入隅Ｒ面 (CR=略図^^;)　r1(mm) : /_R1
rem #c 先端Ｒ面 (CR=略図^^;)　r2(mm) : /_R2
rem #c 線種　(1～9／CR=実線): /_LT
rem #c 線色　(1～9／CR=3): /_LC
rem #hr
rem #e

rem #:5
rem #h0
rem #0 リップ溝形鋼の 図示位置を指示
rem #1 リップ溝形鋼の Ｙ軸方向を指示.
rem #c 描画基点　(1～9／CR=1) : /_PT
rem #c 縦 A　(mm／CR=100) : /_AA
rem #c 横 B　(mm／CR=50) : /_BB
rem #c リップ C　(mm／CR=20) : /_CC
rem #c 厚さ t　(mm／CR=2.3) : /_TT
rem #c 線種　(1～9／CR=実線): /_LT
rem #c 線色　(1～9／CR=3): /_LC
rem #hr
rem #e


rem #:6
rem #h0
rem #0 重量溝形鋼の 図示位置を指示
rem #1 重量溝形鋼の Ｙ軸方向を指示.
rem #c 描画基点　(1～9／CR=1) : /_PT
rem #c 高さ　(mm／CR=200) : /_HH
rem #c 幅　(mm／CR=80) : /_BB
rem #c ウェブ厚　(mm／CR=7.5) : /_TW
rem #c フランジ厚　(mm／CR=11) : /_TF
rem #c 入隅Ｒ面 (CR=略図 ^^;)　r1(mm) : /_R1
rem #c 先端Ｒ面 (CR=略図 ^^;)　r2(mm) : /_R2
rem #c 線種　(1～9／CR=実線): /_LT
rem #c 線色　(1～9／CR=4): /_LC
rem #hr
rem #e


:do1
copy jwc_temp.txt temp.txt > nul
mawk32 -f c:\jww\tool\my_awk\KHGATA.AWK temp.txt %2 %3 %4 %5 %6 %7 %8 %9> jwc_temp.txt
goto END

:do2
copy jwc_temp.txt temp.txt > nul
mawk32 -f c:\jww\tool\my_awk\KCOLUM.AWK temp.txt %2 %3 %4 %5 %6 %7 %8 %9> jwc_temp.txt
goto END

:do3
copy jwc_temp.txt temp.txt > nul
mawk32 -f c:\jww\tool\my_awk\KENKEI.AWK temp.txt %2 %3 %4 %5 %6 %7 %8 %9> jwc_temp.txt
goto END

:do4
copy jwc_temp.txt temp.txt > nul
mawk32 -f c:\jww\tool\my_awk\KANGLE.AWK temp.txt %2 %3 %4 %5 %6 %7 %8 %9> jwc_temp.txt
goto END

:do5
copy jwc_temp.txt temp.txt > nul
mawk32 -f c:\jww\tool\my_awk\KC_CHAN.AWK temp.txt %2 %3 %4 %5 %6 %7 %8 %9> jwc_temp.txt
goto END

:do6
copy jwc_temp.txt temp.txt > nul
mawk32 -f c:\jww\tool\my_awk\KCHAN.AWK temp.txt %2 %3 %4 %5 %6 %7 %8 %9> jwc_temp.txt

:END
del temp.txt >nul
exit


●起動バッチファイルのパスの編集をする。

－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
:do1
copy jwc_temp.txt temp.txt > nul
mawk32 -f c:\jww\tool\my_awk\KHGATA.AWK temp.txt %2 %3 %4 %5 %6 %7 %8 %9> jwc_temp.txt
goto END
－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
上の赤い部分を注目しましょう。
◆mawk32　-->　32bit用AWK言語を表しています。jgawkを使用している場合は「jgawk」と書き変えましょう。
◆-f　-->　スクリプトファイルを使用することを表しています。これはこのままでOK
◆c:\jww\tool\my_awk\KHGATA.AWK　-->　KHGATA.AWKの存在する場所を指示するように書き変えましょう。

このようになります。フォルダ指定は参考としてください。
　　↓　　↓　　↓
－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
:do1
copy jwc_temp.txt temp.txt > nul
jgawk -f c:\jwgaibu\K_DANMEN\KHGATA.AWK temp.txt %2 %3 %4 %5 %6 %7 %8 %9> jwc_temp.txt
goto END
－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－

以下、:do2　～　do6　まで同様に書き変えましょう。

：：ヒント：：
ここまで来ると、「REM #cd」を追加して、c:\から後ろのパスを消す。って作業を考えてくる方がいると思います。（*^_^*）。。


／／／／／／／／／／／／／／／／／／／／／／／／／／／／／／／／／／
（ミニ）用語の説明（せっかくですから、ちょっと上の記述の説明を）

:do1
１番目の実行時のラベルを表す。他の外変では「:exe-1」の記述が多いです。「鋼_断面1.bat」バッチファイルの上の方を確認してください。「goto do%1」の記述があります。これが、「goto exe-%1」ならば、「:exe-1」になります。

copy jwc_temp.txt temp.txt > nul
「jwc_temp.txt」の内容を「temp.txt」にコピーするという意味です。
「> nul」は、MS-DOSウインドウにエコーが表示されないようにする指定です。

mawk32 -f c:\jww\tool\my_awk\KHGATA.AWK
これは、先に説明したから良いですね。(^^ゞ

%2　～　%9
オプション設定です。
　　rem #c 描画基点　(1～9／CR=8): /_PT
　　rem #c 高さ　(mm／CR=250) : /_HH
　　rem #c 幅　(mm／CR=125) : /_BB
　　rem #c ウェブ厚　(mm／CR=6) : /_TW
　　rem #c フランジ厚　(mm／CR=9) : /_TF
　　rem #c フィレット　r(mm)(CR=略図／ｱﾙﾌｧﾍﾞｯﾄ=BH) : /_RR
　　rem #c 線種　(1～9／CR=実線): /_LT
　　rem #c 線色　(1～9／CR=4): /_LC
この８項目を入力した値が、置き換えられます。

> jwc_temp.txt
処理したものを書きだす場所の指定。「jwc_temp.txt」となります。

goto END
バッチファイルの最後「:END」へ移動させる表示です。
「終わらせる。」って意味が解りますよね。これが無いと、次の「:do2」へ進んでしまいます。

ちょっと難しくなったかもしれませんが、この辺を理解してくるとBATファイルの基礎知識が付いてきますよ。


++++当ページ内の掲載については、作者（Gnomon）様より承諾を頂いています。++++

Home

Contents
counter

-

Pickup Entry
Recent Comments
Recent Trackback
Recent Entries
Categories
Archives
Search
Feeds

Page Top